Συνάρτηση SUMPRODUCT Excel

Περίληψη

Η συνάρτηση SUMPRODUCT χρησιμοποιείται για να επιστρέψει το άθροισμα των γινομένων των αντίστοιχων πινάκων που χρησιμοποιείτε ως ορίσματα. Ως προεπιλεγμένη πράξη είναι ο πολλαπλασιασμός, αλλά μπορεί να χρησιμοποιηθεί η πρόσθεση ή αφαίρεση.

Η συνάρτηση SUMPRODUCT μπορεί να χρησιμοποιηθεί σε έναν πίνακα για να εντοπίσουμε το πλήθος ή το άθροισμα δεδομένων που πληρούν κάποια κριτήρια ή να χρησιμοποιηθεί για να υπολογίσετε τον σταθμισμένο μέσο όρο.

Σύνταξη

=SUMPRODUCT(Πίνακας1;[Πίνακας255])

Ορίσματα

Πίνακας1

Είναι υποχρεωτικό όρισμα και αφορά τον πίνακα του οποίου τα στοιχεία θέλετε να πολλαπλασιάσετε και στη συνέχεια να προσθέσετε.

[Πίνακας2...255]

Είναι προαιρετικά ορίσματα πίνακα τα οποία μπορεί να φτάσουν μέχρι και τους 255 πίνακες.

Οδηγίες χρήσης

• Όλα τα ορίσματα θα πρέπει να είναι το ίδιο μέγεθος
• Τα μη αριθμητικά δεδομένα σε ένα πίνακα, αντιμετωπίζονται ως 0

Παράδειγμα

Έστω ότι θέλετε να βρείτε το άθροισμα της κατηγορίας Φρούτα με την βοήθεια της συνάρτησης SUMPRODUCT

=SUMPRODUCT(F4:F18;--(C4:C18="Φρούτα"))

Ανάλυση συνάρτησης:

F4:F18 θα επιστρέψει τις τιμές {14,16;5,28;4,7;3,9;4,59;2,8;5,1;2,42;1,4;3,99;6,5;7,4;12,6;22,5;2,4}

C4:C18="Φρούτα' θα επιστρέψει τις τιμές

{FALSE;TRUE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE;FALSE;TRUE;TRUE;TRUE;TRUE;FALSE;FALSE}

Αυτό που κάνει η συνάρτηση SUMPRODUCT είναι να προσθέτει τα γινόμενα των 2 πινάκων

{14,16;5,28;4,7;3,9;4,59;2,8;5,1;2,42;1,4;3,99;6,5;7,4;12,6;22,5;2,4} * {FALSE;TRUE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE;FALSE;TRUE;TRUE;TRUE;TRUE;FALSE;FALSE}

{14,16*FALSE + 5,28*TRUE +4,7*FALSE...}

Για να λειτουργήσει σωστά η συνάρτηση θα πρέπει να μετατρέψετε τις λογικές τιμές TRUE και FALSE σε 1 και 0. Αυτό γίνεται αν το δεύτερο όρισμα γραφτεί ως εξής: --(C4:C18).

Το --(λογική τιμή) μετατρέπει μία λογική τιμή σε 1 ή 0

Παράδειγμα με πολλαπλά κριτήρια

Έστω ότι θέλουμε να βρούμε το άθροισμα του συνόλου των παραγγελιών για την κατηγορία Φρούτα αλλά μόνο όπου υπάρχει η ποσότητα>4. Η συνάρτηση θα έχει την παρακάτω μορφή:

=SUMPRODUCT(F4:F18;--(C4:C18="Φρούτα");--(E4:E18>4))

ότι κριτήρια βάζουμε με τους τελεστές σύγκρισης θα πρέπει να μπαίνουν σε --() έτσι ώστε να μετατρέπονται οι τιμές TRUE / FALSE σε 1 / 0

Τα κριτήρια λειτουργούν συζευτικά. Δηλαδή πρέπει να πληρούνται όλες οι προϋποθέσεις για να εμφανίσει αποτέλεσμα.

Πολλαπλό κριτήριο με Ή

Έστω ότι θέλουμε το άθροισμα των πωλήσεων από την κατηγορία Φρούτα και Λαχανικά.

Η συνάρτηση θα είναι: 

=SUMPRODUCT(F4:F18;(C4:C18="Λαχανικά")+(C4:C18="Φρούτα"))

Ανάλυση συνάρτησης

(C4:C18="Λαχανικά")+(C4:C18="Φρούτα")

έχουμε 2 ορίσματα τα οποία αφορούν την ίδια στήλη C4:C18 και ψάχνουμε 2 τιμές, τα Φρούτα και Λαχανικά. Για να το πετύχουμε αυτό, χρησιμοποιούμε τον τελεστή +.

Σημείωση: Όταν χρησιμοποιούμε τελεστή + (Ή), *(ΚΑΙ) δεν είναι απαραίτητο να βάλουμε τους πίνακες σε --() καθώς αυτό γίνεται από το Excel αυτόματα. Σε κάθε άλλη περίπτωση που επιστρέφεται λογική τιμή από την συνάρτηση SUMPRODUCT, είναι απαραίτητο να βάλετε τις τιμές TRUE, FALSE σε --() για να μετατραπούν σε 1,0/